mirror of
https://git.savannah.gnu.org/git/guix.git
synced 2025-02-02 16:17:27 +01:00
2be6b5e2ee
Fix the following fatal error on ‘guix system reconfigure’:
Backtrace:
18 (primitive-load "/home/nckx/.config/guix/current/bin/guix")
In guix/ui.scm:
1620:12 17 (run-guix-command _ . _)
In ice-9/boot-9.scm:
829:9 16 (catch _ _ #<procedure 7a7caa2d4c80 at guix/ui.scm:587:2 (key c)> _)
829:9 15 (catch _ _ #<procedure 7a7caa2d4c98 at guix/ui.scm:710:6 (key proc format-string format-args . …> …)
In guix/scripts/system.scm:
1325:8 14 (_)
In guix/status.scm:
768:4 13 (call-with-status-report _ _)
In guix/scripts/system.scm:
1181:4 12 (process-action _ _ _)
In guix/store.scm:
623:10 11 (call-with-store _)
1800:24 10 (run-with-store _ _ #:guile-for-build _ #:system _ #:target _)
In guix/scripts/system.scm:
920:13 9 (_ _)
409:8 8 (_ _)
In unknown file:
7 (primitive-load "/gnu/store/dha7j9gcz3vgb8cy7vfvvaswwsywrrzj-activate")
In ice-9/boot-9.scm:
260:13 6 (for-each #<procedure primitive-load (_)> _)
In unknown file:
5 (primitive-load "/gnu/store/ql1xjxrssxm51z2bn2v6l3mlrncij84h-activate-service")
In ice-9/eval.scm:
619:8 4 (_ #f)
196:35 3 (_ #f)
196:27 2 (_ #f)
223:20 1 (proc #<directory (guile-user) 1fa4140>)
In unknown file:
0 (%resolve-variable (7 . cut) #<directory (guile-user) 1fa4140>)
ERROR: In procedure %resolve-variable:
error: cut: unbound variable
Reported-by: Alex McGrath on #guix.
* gnu/services/nix.scm (nix-activation): Import and use (srfi srfi-26).
114 lines
3.8 KiB
Scheme
114 lines
3.8 KiB
Scheme
;;; GNU Guix --- Functional package management for GNU
|
||
;;; Copyright © 2019 Oleg Pykhalov <go.wigust@gmail.com>
|
||
;;;
|
||
;;; This file is part of GNU Guix.
|
||
;;;
|
||
;;; GNU Guix is free software; you can redistribute it and/or modify it
|
||
;;; under the terms of the GNU General Public License as published by
|
||
;;; the Free Software Foundation; either version 3 of the License, or (at
|
||
;;; your option) any later version.
|
||
;;;
|
||
;;; GNU Guix is distributed in the hope that it will be useful, but
|
||
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||
;;; GNU General Public License for more details.
|
||
;;;
|
||
;;; You should have received a copy of the GNU General Public License
|
||
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
|
||
|
||
(define-module (gnu services nix)
|
||
#:use-module (gnu packages admin)
|
||
#:use-module (gnu packages package-management)
|
||
#:use-module (gnu services base)
|
||
#:use-module (gnu services configuration)
|
||
#:use-module (gnu services shepherd)
|
||
#:use-module (gnu services web)
|
||
#:use-module (gnu services)
|
||
#:use-module (gnu system shadow)
|
||
#:use-module (guix gexp)
|
||
#:use-module (guix packages)
|
||
#:use-module (guix records)
|
||
#:use-module (guix store)
|
||
#:use-module (srfi srfi-1)
|
||
#:use-module (srfi srfi-26)
|
||
#:export (nix-service-type))
|
||
|
||
;;; Commentary:
|
||
;;;
|
||
;;; This module provides a service definition for the Nix daemon.
|
||
;;;
|
||
;;; Code:
|
||
|
||
|
||
;;;
|
||
;;; Accounts
|
||
;;;
|
||
|
||
;; Copied from gnu/services/base.scm
|
||
(define* (nix-build-accounts count #:key
|
||
(group "nixbld")
|
||
(shadow shadow))
|
||
"Return a list of COUNT user accounts for Nix build users with the given
|
||
GID."
|
||
(unfold (cut > <> count)
|
||
(lambda (n)
|
||
(user-account
|
||
(name (format #f "nixbld~2,'0d" n))
|
||
(system? #t)
|
||
(group group)
|
||
(supplementary-groups (list group "kvm"))
|
||
(comment (format #f "Nix Build User ~2d" n))
|
||
(home-directory "/var/empty")
|
||
(shell (file-append shadow "/sbin/nologin"))))
|
||
1+
|
||
1))
|
||
(define (nix-accounts _)
|
||
"Return the user accounts and user groups."
|
||
(cons (user-group
|
||
(name "nixbld")
|
||
(system? #t)
|
||
|
||
;; Use a fixed GID so that we can create the store with the right
|
||
;; owner.
|
||
(id 40000))
|
||
(nix-build-accounts 10 #:group "nixbld")))
|
||
|
||
(define (nix-activation _)
|
||
"Return the activation gexp."
|
||
(with-imported-modules '((guix build utils)
|
||
(srfi srfi-26))
|
||
#~(begin
|
||
(use-modules (guix build utils)
|
||
(srfi srfi-26))
|
||
(for-each (cut mkdir-p <>) '("/nix/store" "/nix/var/log"
|
||
"/nix/var/nix/gcroots/per-user"
|
||
"/nix/var/nix/profiles/per-user"))
|
||
(chown "/nix/store"
|
||
(passwd:uid (getpw "root")) (group:gid (getpw "nixbld01")))
|
||
(chmod "/nix/store" #o775)
|
||
(for-each (cut chmod <> #o777) '("/nix/var/nix/profiles"
|
||
"/nix/var/nix/profiles/per-user")))))
|
||
|
||
(define (nix-shepherd-service _)
|
||
"Return a <shepherd-service> for Nix."
|
||
(list
|
||
(shepherd-service
|
||
(provision '(nix-daemon))
|
||
(documentation "Run nix-daemon.")
|
||
(requirement '())
|
||
(start #~(make-forkexec-constructor
|
||
(list (string-append #$nix "/bin/nix-daemon"))))
|
||
(respawn? #f)
|
||
(stop #~(make-kill-destructor)))))
|
||
|
||
(define nix-service-type
|
||
(service-type
|
||
(name 'nix)
|
||
(extensions
|
||
(list (service-extension shepherd-root-service-type nix-shepherd-service)
|
||
(service-extension account-service-type nix-accounts)
|
||
(service-extension activation-service-type nix-activation)))
|
||
(default-value '())
|
||
(description "Run the Nix daemon.")))
|
||
|
||
;;; nix.scm ends here
|